plugins {
    id 'java'
    id 'java-library'
    id 'maven-publish'
    id 'signing'
}

apply from: '../spotless.gradle'

group "org.bdware.bdcontract"
version "0.7.5"
sourceCompatibility = 1.8
repositories {
    mavenCentral()
    mavenLocal()
}

dependencies {
    implementation 'com.google.code.gson:gson:2.9.1'
    implementation project(":gmhelper")
    implementation project(":sdk-java")
    implementation 'org.bouncycastle:bcpkix-jdk15on:1.69'
    implementation 'org.bouncycastle:bcprov-jdk15on:1.69'
    implementation 'org.apache.httpcomponents:httpclient:4.5.13'
    implementation 'org.apache.httpcomponents:httpmime:4.5.13'
    implementation 'org.bdware.doip:bdosclient:0.0.8'
   // implementation 'org.bdware.doip:doip-audit-tool:1.2.4'
    testImplementation 'junit:junit:4.13.2'
}

task copyLibs(type: Copy, dependsOn: [':ypk-deploy-tool:jar']) {
    from configurations.runtimeClasspath
    into "./build/output/libs/"
}
task copyScript(type: Copy) {
    from "./docker/javarun.sh"
    from "./docker/docker-compose/deployentry.json"
    into "./build/output/"
}
task copyJar(type: Copy, dependsOn: [":ypk-deploy-tool:copyLibs", ":ypk-deploy-tool:copyScript"]) {
    from "./build/libs/$project.name-${project.version}.jar"
    into "./build/output"
    rename { String fileName -> "${project.name}.jar" }
    doFirst {
        println "copyJar start"
    }
}


task classJar(type: Jar, dependsOn: classes) {
    classifier = "jar"
}
task sourceJar(type: Jar, dependsOn: classes) {
    archiveClassifier = "sources"
    classifier = "sources"
    from sourceSets.main.allSource
}

tasks.withType(Javadoc) {
    options.addStringOption('Xdoclint:none', '-quiet')
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    archiveClassifier = 'javadoc'
    classifier = "javadoc"
    exclude {
        details -> details.file.getAbsolutePath().contains("/gm/")
    }
    from javadoc.destinationDir
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            groupId project.group
            artifactId "ypk-deploy-tool"
            version "${version}"
            from components.java
            artifact sourceJar
            artifact javadocJar
            artifact classJar
            pom {
                name = "bdware-ypk-deploy-tool"
                description = "ypk-deploy-tool"
                url = "https://gitee.com/BDWare/ypk-deploy-tool"
                licenses {
                    license {
                        name = "Mulan PSL v2"
                        url = "http://license.coscl.org.cn/MulanPSL2"
                    }
                }
                developers {
                    developer {
                        id = "dataware"
                        email = "caihq@pku.edu.cn"
                    }
                }
                scm {
                    connection = "scm:git:https://gitee.com/BDWare/ypk-deploy-tool.git"
                    developerConnection = "scm:git:https://gitee.com/BDWare/ypk-deploy-tool.git"
                    url = "https://gitee.com/BDWare/ypk-deploy-tool"
                }
            }

        }
    }
    repositories {
        maven {
            name 'bdwareSnapshotRepository'
            url 'https://oss.sonatype.org/content/repositories/snapshots'
            credentials {
                username = "${NEXUS_USERNAME}"
                password = "${NEXUS_PASSWORD}"
            }
        }
        maven {
            name 'bdwareRepository'
            url 'https://oss.sonatype.org/service/local/staging/deploy/maven2'
            credentials {
                username = "${NEXUS_USERNAME}"
                password = "${NEXUS_PASSWORD}"
            }
        }
    }
}
signing {
    sign publishing.publications.mavenJava
}